Unlike most layout tools, VeeCAD is optimized for stripboards, i.e. producing a stripboard layout is pretty fast. Since VeeCAD relies on external schematic editors, so you need to import your completed netlist into VeeCAD before the fun can begin. In fact, every time you make a change to the netlist you must tell VeeCAD about it, by importing the new, improved netlist.
Now, if you're like me, your schematics drawings evolve over time. You tweak them, fix a netlist bug, replace a component, etc. And with VeeCAD, every time the netlist changes, you must click through a series of windows to get VeeCAD onto the same page as your schematic editor. ..... Hmmm......this quickly gets old.
There must be a less boring way to keep VeeCAD on top of my changes?
If your schematic editor is DesignSpark PCB (a free tool from RS Components), and you don't mind installing yet another great, free tool (AutoIt (see Wikipedia), the answer is now Yes!
Below is a small AutoIt script I made, which will click its way through DesignSparks' menus to export your (currently open) DesignSpark schematic to a temporary file, and then click its way through VeeCAD's menus to import the temp file as a netlist. Taks approximately 2 seconds.
All in one go, and without any setup or configuration :-)
The script assumes DesignSpark and VeeCAD are both running on your PC when the script starts.
Simply copy the script below into a text editor, and save it with the file extension "au3". Run it by double-clicking it.
And as always with scripts: Remember to save your work before running the script.
#cs --------------------------------------------------------------------------------------
Are you tired of the repetetive mouse clicking required to export a DesignSpark netlist
into VeeCad?
This AutoIt script exports the currently open DesingSpark schematics (in Generic Netlist
format) to a file on your hard disk. The script then imports this file into the current
board in VeeCad (in Easy-PC format). (The file will be created in the same directory as this script runs from).
The script assumes you have DesignSpark running and displaying a schematic,
and VeeCad displaying the board you want to import the netlist into.
Tested with Windows XP, AutoIt version 3.3.6.1, SparkDesign PCB 3.0, and VeeCAD 2.26
Should be compatible with most versions, if not you can easily adapt it. Have fun :-)
Standard disclaimer: Comes with no guarantee of fitness for any purpose.
Copyright: www.leifove.com License: GPL version 3.0
#ce ---------------------------------------------------------------------------------------
AutoItSetOption("MustDeclareVars", 1) ; To avoid spelling mistakes in variable names.
; ----------------------------- Define some useful variables ------------------------------
Dim $netlist_filename = "netlist_from_designspark.net" ; Filetype must be .net
Dim $full_path_name_to_netlist = @ScriptDir & "\" & $netlist_filename ; Same dir as this script
Dim $timeout_period = 3 ; The longest this script is willing to wait. In seconds.
Dim $veecad_window_title_start = "VeeCAD :" ; Try changing this if the two programs are not found,
Dim $designspark_window_title_start = "DesignSpark" ; but don't make the titles longer than necessary!
Dim $veecad_windows, $designspark_windows
; --------------------- Define a handy functions we are going to need ----------------------
Func ExitIfWindowNeverAppears($window_title)
If (0 = WinWait($window_title, "", $timeout_period)) Then
MsgBox(48, "Script terminated.", _
"Lost my patience waiting for the " & $window_title & " window to appear.")
Exit
EndIf
WinActivate($window_title) ; Just in case, probably not necessary.
EndFunc
; ---------- Verify that DesignSpakr and VeeCAD are running, and in the correct state ------
$designspark_windows = WinList($designspark_window_title_start) ; Count the number of open DesignSpark windows
If $designspark_windows[0][0] <> 1 Then
MsgBox (48, "Script terminated.", _
"There must be one (and only one) open DesignSpark window!. I found " & $designspark_windows[0][0] & ".")
Exit
EndIf
If WinExists("Reports") Then
MsgBox (48, "Script terminated.", "Can't run when DesignSpark's Reports window is open.")
Exit
EndIf
If WinExists("Output Netlist") Then
MsgBox (48, "Script terminated.", "Can't run when DesignSpark's Output Netlist window is open.")
Exit
EndIf
$veecad_windows = WinList($veecad_window_title_start) ; Count the number of open VeeCAD windows
If $veecad_windows[0][0] <> 1 Then
MsgBox (48, "Script terminated.", "There must be one (and only one) open VeeCAD window! I found " & $veecad_windows[0][0] & ".")
Exit
EndIf
If WinExists("Import Netlist") Then
MsgBox (48, "Script terminated.", "Can't run when VeeCAD's Import Netlist window is open.")
Exit
EndIf
; ----------------- Export a netlist from the current DesignSpark window --------------------
ExitIfWindowNeverAppears( $designspark_window_title_start )
Send( "!o" ) ; "Output"
Send( "r" ) ; "Reports ..."
; Work in the Reports window
ExitIfWindowNeverAppears ( "Reports")
ControlFocus ( "Reports", "", 1100)
; I could not make ControlCommand work consitently when trying to
; select 'Generic Netlist' in the Reports' listbox:
; ControlCommand( "Reports", "", "ListBox1" , "SelectString", 'Generic')
; ,so the next two lines are a work-around:
ControlSend ("Reports", "", 1100, "{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}{UP}")
ControlSend ("Reports", "", 1100, "{DOWN}{DOWN}{DOWN}{DOWN}") ; 4th item from the top.
Send( "!r" ) ; "Run" button
; Work in the Output Netlist window
ExitIfWindowNeverAppears( "Output Netlist" )
ControlCommand( "Output Netlist", "", 1030 , "Check") ; Include components
ControlCommand( "Output Netlist", "", 1031 , "Check") ; Include nets
ControlCommand( "Output Netlist", "", 1033 , "UnCheck") ; Don't want to view netlist file
ControlSetText( "Output Netlist", "", 1035 , $full_path_name_to_netlist ) ; Where to save file.
WinWaitActive ( "Output Netlist" ) ; Since we have been focused on panels
ControlClick ( "Output Netlist", "", 1) ; Click "Generate". This also closes window.
; Close the Reports window
WinActivate ( "Reports")
ControlClick( "Reports", "", 2) ; Click "Close"
; ----------------------------- Import netlist into VeeCad -----------------------
ExitIfWindowNeverAppears( $veecad_window_title_start )
Send( "!n" ) ; "Netlist"
Send( "i" ) ; "Import"
ExitIfWindowNeverAppears( "Import Netlist")
ControlCommand( "Import Netlist", "", "TComboBox1" , "SelectString", 'Easy-PC') ; Netlist Format
ControlSetText( "Import Netlist", "", "TEdit1" , $full_path_name_to_netlist ) ; Netlist Filename
WinActivate( "Import Netlist") ; Focus on window, since we have been focused on panels
ControlClick( "Import Netlist", "", "TButton5") ; Click "Import"
; ------------------ Good, we're all done with the export and import -------------
MsgBox(0, "Done!", "Netlist export and import finished.") ; Comment out this line to skip confirmation.
Exit
The above script works by pretending to be a human operator clicking a mouse and selecting menu items by name reference. Should the developers behind DesignSpark or VeeCAD in the future decide to rename the controls in their GUIs, the script may stop working. In that case, have a look inside AutoIt's excellent Help function and I'm sure you'll figure out how to tweak my script to make it run again :-)
Have fun!
No comments:
Post a Comment